University of MS, Phys. 709 Fall 2018
Problem Set 1 supplement

Author: Leo C. Stein (lcstein@olemiss.edu)
Date: Fall 2018

FW 1.9

V[r_]:=((-λ)/r)Exp[-r]
Veff[r_]:=V[r]+((ℓ^2)/(2 (r^2)))

D[Veff[r],r];
dVeffdr=Collect[%,{Exp[__]},Simplify]

Simplify[dVeffdr==0,Assumptions->{λ>0,ℓ>0,r>0}]

FW19Plot[α_]:=Plot[{Exp[r],r(1+r) α},{r,0,4},PlotRange->{0,20},Frame->True,PlotLegends->{"(e^r)",ToString[α]<>"r(1+r)"},FrameLabel->{"r",None,"α="<>ToString[α],None}]

Manipulate[FW19Plot[α],{{α,1},0,2}]

Show[FW19Plot[1.4],FW19Plot[1.1],FrameLabel->"r"]
Export[NotebookDirectory[]<>"FW1_9.pdf",%];

Veff''[r]==0/.{Exp[-r]->expMinusr}
First@Solve[%,expMinusr]
Veff'[r]==0/.{Exp[-r]->expMinusr}/.%
rDoubleRootSol=Last@Solve[%,r]
λCritSol=First@Solve[{Veff'[r]==0}/.rDoubleRootSol,λ]//Simplify
%//N

λcrit=λ/.λCritSol/.ℓ->1

λs={1.1,λcrit,1.4};

Plot[Evaluate[Veff[r]/.{λ->λs,ℓ->1}],{r,0,4},Frame->True,FrameLabel->{"r","(Subscript[V, eff])"},PlotLegends->(("(λ/(ℓ^2))="<>ToString@N@#)&/@λs)]
Export[NotebookDirectory[]<>"FW1_9_Veff.pdf",%];